* GRAPHICS
*
DISIRQ MOV  R8,*S+
       STST R8
       ANDI R8,>F
       MOV  R8,@WHOHO
       LIMI 0
       RT
 
RESIRQ DECT S
       MOV  *S,R8
       DATA >0300    'LIMI X'
WHOHO  DATA 0
       RT
 
QCLRG1 MOV  R11,*S+
       BL   @DISIRQ
       LI   R0,' '*256
       MOVB R0,R1
       CLR  R0
       BL   @$XYNA1
       MOVB R1,R0
       BL   @$SETWR
       LI   R1,768
CLRG1A MOVB R0,@$VDPWD
       DEC  R1
       JNE  CLRG1A
       BL   @RESIRQ
       DECT S
       MOV  *S,R11
       RT
*
QREPVR MOV  R11,*S+
       BL   @DISIRQ
       ORI  R2,>4000
       SWPB R2
       MOVB R2,@$VDPWA
       SWPB R2
       MOVB R2,@$VDPWA
       ANDI R2,>3FFF
       A    R3,R2
$RPLP  MOVB R0,@$VDPWD
       DEC  R3
       JNE  $RPLP
       BL   @RESIRQ
       DECT S
       MOV  *S,R11
       RT
*
QWRREG MOV  R11,*S+
       BL   @DISIRQ
       MOVB @$VDPRS,@$VDPST
       MOVB R0,@$VDPWA
       SWPB R0
       ORI  R0,>8000
       MOVB R0,@$VDPWA
       BL   @RESIRQ
       DECT S
       MOV  *S,R11
       RT
*
QYXNA1 SWPB R0
QXYNA1 CLR  R3
       MOVB R0,R3
       SWPB R3
       MOVB R3,R0
       SLA  R0,5
       A    R0,R3
       MOV  R1,R4
       CLR  R1
       MOVB @$SHAD2,R1
       SWPB R1
       LI   R0,>0400
       MPY  R0,R1
       A    R3,R2
       MOV  R4,R1
       RT
*
QSETWR MOV  R11,*S+
       BL   @DISIRQ
       ORI  R2,>4000
       SWPB R2
       MOVB R2,@$VDPWA
       SWPB R2
       MOVB R2,@$VDPWA
       ANDI R2,>3FFF
       BL   @RESIRQ
       DECT S
       MOV  *S,R11
       RT
*
QRTGRA MOV  R3,R1
QWRGRA MOVB R1,@$GRMWA
       SWPB R1
       MOVB R1,@$GRMWA
       SWPB R1
       RT
*
QSVGRA MOVB @$GRMRA,R3
       SWPB R3
       MOVB @$GRMRA,R3
       SWPB R3
       DEC  R3
       RT
*
QBACK  MOV  R11,*S+
       LI   R1,>0700
       SWPB R0
       MOVB R1,R0
       SWPB R0
       BL   @$WRREG
       DECT S
       MOV  *S,R11
       RT
*
QTIKBD MOV  R11,*S+
       BL   @DISIRQ
       LWPI $GPLWS
       BL   @>E
       LWPI MAINWS
       BL   @RESIRQ
       DECT S
       MOV  *S,R11
       RT
*
QBYTVR MOV  R11,*S+
       BL   @DISIRQ
       ORI  R2,>4000
       SWPB R2
       MOVB R2,@$VDPWA
       SWPB R2
       MOVB R2,@$VDPWA
       ANDI R2,>3FFF
$WRTB  MOVB R0,@$VDPWD
       INC  R2
       BL   @RESIRQ
       DECT S
       MOV  *S,R11
       RT
*
QRNDOM MOVB @$RAND,R0
       SLA  R0,7
       ANDI R0,>8000
       A    @$RAND,R0
       SRC  R0,15
       MOV  R0,@$RAND
       RT
*
QRADDR MOV  R11,*S+
       MOV  R1,R6
       LI   R2,>0012
       LIMI 0
       BL   @ENQCMD
       MOVB R6,R1
       SRL  R1,8
       LI   R0,8
       BL   @ENQUE
       MOV  R6,R1
       LI   R0,8
       BL   @ENQUE
       MOVB @$NBYTE,R1
       SRL  R1,8
       LI   R0,5
       BL   @ENQUE
       DECT S
       MOV  *S,R11
       RT
